M5Stack CORE2にドメイン名でアクセスする

#include <M5Unified.h>
#include <WiFi.h>
#include <WebServer.h>
#include <ESPmDNS.h> //mDNS追加

const char *ssid = "**************"; //Your WiFi SSID
const char *password = "*************"; //Your WIFi パスワード

//IPAddress ip; //IP address
WebServer server(80); //WebServerクラスのインスタンス生成(HTTPのポート番号)

void handleRoot() {
  server.send(200, "text/plain", "Response from M5Stack CORE2. \n...Root Test mDNS");
}
void handleSub1() {
  server.send(200, "text/plain", "Response from M5Stack CORE2. \n...Sub1 Test mDNS");
}
void handleSub2() {
  server.send(200, "text/plain", "Response from M5Stack CORE2. \n...Sub2 Test mDNS");
}

void handleNotFound() {
  String message = "File Not Found\n\n";
  message += "URI: ";
  message += server.uri();
  message += "\nMethod: ";
  message += (server.method() == HTTP_GET) ? "GET" : "POST";
  message += "\nArguments: ";
  message += server.args();
  message += "\n";
  for (uint8_t i = 0; i < server.args(); i++) {
    message += " " + server.argName(i) + ": " + server.arg(i) + "\n";
  }
  server.send(404, "text/plain", message);
}

void setup(void) {
  auto cfg = M5.config();
  M5.begin(cfg);

  M5.Display.fillScreen(TFT_WHITE);
  M5.Display.setTextColor(TFT_BLACK, TFT_WHITE);
  M5.Display.setTextSize(2);
  M5.Display.print("\n** Test WebServer mDNS **\n\n");
  M5.Display.print("Connecting");

  WiFi.mode(WIFI_STA); //ステーションモード。M5Stackを子機として接続
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    M5.Display.print(".");
  }

  M5.Display.print("\n\nWiFi connected!\n\n");
  //M5.Display.print("IP address: ");
  //ip = WiFi.localIP(); //IP address取得
  //M5.Display.print(ip); //IP address表示

  String DomainName = "my-m5core2"; //ドメイン名 my-m5core2.local
  M5.Display.printf("\nDomainName: %s",DomainName); //ドメイン名表示

  if (!MDNS.begin(DomainName)) {
    M5.Display.println("Error setting up MDNS responder!");
    while (1) {
      delay(1000);
    }
  }

  server.on("/", handleRoot); //IPアドレスのルートにアクセスされたとき
  server.on("/sub1", handleSub1); //Sub1にアクセスされたとき
  server.on("/sub2", handleSub2); //Sub2にアクセスされたとき
  server.onNotFound(handleNotFound); //存在しないリソースにアクセスされたとき

  server.begin(); //Webサーバー開始
  MDNS.addService("http", "tcp", 80); //mDNSサービス追加（サービス, プロトコル, ポート）
}

void loop(void) {
  server.handleClient(); //クライアントのリクエスト待ち
}